Rust: Cross-crate path resolution

Author: hvitved

rust/ql/integration-tests/hello-workspace/exe/src/main.rs

@@ -1,7 +1,7 @@
-use lib::a_module::hello; // $ MISSING: item=HELLO
+use lib::a_module::hello; // $ item=HELLO
 
 mod a_module;
 
 fn main() {
-    hello(); // $ MISSING: item=HELLO
+    hello(); // $ item=HELLO
 }

rust/ql/lib/codeql/rust/elements/internal/CrateImpl.qll

@@ -30,6 +30,25 @@ module Impl {
       i = 4 and result = ")"
     }
 
+    /** Gets the source file that defines this crate, if any. */
+    SourceFile getSourceFile() { result.getFile() = this.getModule().getFile() }
+
+    /**
+     * Gets a source file that belongs to this crate, if any.
+     *
+     * For now, this is a simple heuristic that returns any source file that is in
+     * a reflexive transitive subfolder of the folder containing the source file of
+     * the crate.
+     */
+    pragma[nomagic]
+    SourceFile getASourceFile() {
+      result.getFile().getParentContainer*() = this.getSourceFile().getFile().getParentContainer() and
+      not exists(Crate other |
+        result = other.getSourceFile() and
+        other != this
+      )
+    }
+
     override Location getLocation() { result = this.getModule().getLocation() }
   }
 }

rust/ql/lib/codeql/rust/internal/PathResolution.qll

@@ -73,7 +73,7 @@ final class Namespace extends TNamespace {
  * - https://doc.rust-lang.org/reference/visibility-and-privacy.html
  * - https://doc.rust-lang.org/reference/names/namespaces.html
  */
-abstract class ItemNode extends AstNode {
+abstract class ItemNode extends Locatable {
   /** Gets the (original) name of this item. */
   abstract string getName();
 
@@ -122,6 +122,10 @@ abstract class ItemNode extends AstNode {
     or
     useImportEdge(this, name, result)
     or
+    crateDefEdge(this, name, result)
+    or
+    crateDependencyEdge(this, name, result)
+    or
     // items made available through `use` are available to nodes that contain the `use`
     exists(UseItemNode use |
       use = this.getASuccessorRec(_) and
@@ -180,7 +184,7 @@ abstract class ItemNode extends AstNode {
     this = result.(ImplOrTraitItemNode).getAnItemInSelfScope()
     or
     name = "crate" and
-    result.(SourceFileItemNode).getFile() = this.getFile()
+    this = result.(Crate).getASourceFile()
   }
 
   /** Gets the location of this item. */
@@ -214,6 +218,27 @@ private class SourceFileItemNode extends ModuleLikeNode, SourceFile {
   override TypeParam getTypeParam(int i) { none() }
 }
 
+private class CrateItemNode extends ItemNode instanceof Crate {
+  /** Gets the module node that defines this crate. */
+  pragma[nomagic]
+  ModuleLikeNode getModuleNode() {
+    result = super.getSourceFile()
+    or
+    not exists(super.getSourceFile()) and
+    result = super.getModule()
+  }
+
+  override string getName() { result = "(crate)" }
+
+  override Namespace getNamespace() {
+    result.isType() // can be referenced with `crate`
+  }
+
+  override Visibility getVisibility() { none() }
+
+  override TypeParam getTypeParam(int i) { none() }
+}
+
 /** An item that can occur in a trait or an `impl` block. */
 abstract private class AssocItemNode extends ItemNode, AssocItem {
   /** Holds if this associated item has an implementation. */
@@ -600,6 +625,31 @@ private predicate fileImportEdge(Module mod, string name, ItemNode item) {
   )
 }
 
+/**
+ * Holds if crate `c` defines the item `i` named `name`.
+ */
+pragma[nomagic]
+private predicate crateDefEdge(CrateItemNode c, string name, ItemNode i) {
+  i = c.getModuleNode().getASuccessor(name)
+}
+
+/**
+ * Holds if `source` depends on crate `dep` named `name`.
+ *
+ * Does not yet take dependency renaming into account.
+ */
+pragma[nomagic]
+private predicate crateDependencyEdge(ModuleLikeNode source, string name, Crate dep) {
+  exists(CrateItemNode c |
+    dep = c.(Crate).getADependency() and
+    dep.getName() = name
+  |
+    source = c.getModuleNode()
+    or
+    source = c.(Crate).getASourceFile()
+  )
+}
+
 private predicate useTreeDeclares(UseTree tree, string name) {
   not tree.isGlob() and
   not exists(tree.getUseTreeList()) and
@@ -837,3 +887,44 @@ private predicate useImportEdge(Use use, string name, ItemNode item) {
     name != "_"
   )
 }
+
+/** Provides predicates for debugging the path resolution implementation. */
+private module Debug {
+  private Locatable getRelevantLocatable() {
+    exists(string filepath, int startline, int startcolumn, int endline, int endcolumn |
+      result.getLocation().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn) and
+      filepath.matches("%/build_steps/mod.rs") and
+      startline = 17
+    )
+  }
+
+  ItemNode debugResolvePath(RelevantPath path) {
+    path = getRelevantLocatable() and
+    result = resolvePath(path)
+  }
+
+  predicate debugCrateDependencyEdge(ModuleLikeNode source, string name, Crate dep) {
+    source = getRelevantLocatable() and
+    crateDependencyEdge(source, name, dep)
+  }
+
+  predicate debugUseImportEdge(Use use, string name, ItemNode item) {
+    use = getRelevantLocatable() and
+    useImportEdge(use, name, item)
+  }
+
+  ItemNode debugGetASuccessorRec(ItemNode i, string name) {
+    i = getRelevantLocatable() and
+    result = i.getASuccessor(name)
+  }
+
+  predicate debugFileImportEdge(Module mod, string name, ItemNode item) {
+    mod = getRelevantLocatable() and
+    fileImportEdge(mod, name, item)
+  }
+
+  predicate debugFileImport(Module m, SourceFile f) {
+    m = getRelevantLocatable() and
+    fileImport(m, f)
+  }
+}

rust/ql/test/library-tests/path-resolution/path-resolution.expected

@@ -129,7 +129,7 @@ resolvePath
 | main.rs:274:16:274:16 | T | main.rs:268:7:268:7 | T |
 | main.rs:275:14:275:17 | Self | main.rs:266:5:276:5 | trait MyParamTrait |
 | main.rs:275:14:275:33 | ...::AssociatedType | main.rs:270:9:270:28 | TypeAlias |
-| main.rs:284:13:284:17 | crate | main.rs:1:1:499:2 | SourceFile |
+| main.rs:284:13:284:17 | crate | main.rs:0:0:0:0 | Crate(main@0.0.1) |
 | main.rs:284:13:284:22 | ...::m13 | main.rs:279:1:292:1 | mod m13 |
 | main.rs:284:13:284:25 | ...::f | main.rs:280:5:280:17 | fn f |
 | main.rs:284:13:284:25 | ...::f | main.rs:280:19:281:19 | struct f |
@@ -220,7 +220,7 @@ resolvePath
 | main.rs:479:5:479:32 | ...::f | my2/nested2.rs:3:9:5:9 | fn f |
 | main.rs:480:5:480:5 | f | my2/nested2.rs:3:9:5:9 | fn f |
 | main.rs:481:5:481:5 | g | my2/nested2.rs:7:9:9:9 | fn g |
-| main.rs:482:5:482:9 | crate | main.rs:1:1:499:2 | SourceFile |
+| main.rs:482:5:482:9 | crate | main.rs:0:0:0:0 | Crate(main@0.0.1) |
 | main.rs:482:5:482:12 | ...::h | main.rs:50:1:69:1 | fn h |
 | main.rs:483:5:483:6 | m1 | main.rs:13:1:37:1 | mod m1 |
 | main.rs:483:5:483:10 | ...::m2 | main.rs:18:5:36:5 | mod m2 |